Version analysis of PLL1 (Part 2 of 3) - Elite on the BBC Micro and NES

This code appears in the following versions (click to see it in the source code):

Cassette, Disc (flight), 6502 Second Processor, Master and Electron

Code variations between these versions are shown below.

       Name: PLL1 (Part 2 of 3)
       Type: Subroutine
   Category: Drawing planets
    Summary: Draw Saturn on the loading screen (draw the stars)
  Deep dive: Drawing Saturn on the loading screen


                        \ The following loop iterates CNT2(1 0) times, i.e. &1DD
                        \ or 477 times, and draws the background stars on the
                        \ loading screen

.PLL2

 JSR DORND              \ Set A and X to random numbers, say A = r3

 TAX                    \ Set X = A
                        \       = r3

 JSR SQUA2              \ Set (A P) = A * A
                        \           = r3^2

 STA ZP+1               \ Set ZP+1 = A
                        \          = r3^2 / 256

 JSR DORND              \ Set A and X to random numbers, say A = r4

 STA YY                 \ Set YY = r4

 JSR SQUA2              \ Set (A P) = A * A
                        \           = r4^2

 ADC ZP+1               \ Set A = A + r3^2 / 256
                        \       = r4^2 / 256 + r3^2 / 256
                        \       = (r3^2 + r4^2) / 256

 CMP #&11               \ If A < 17, jump down to PLC2 to skip to the next pixel
 BCC PLC2

 LDA YY                 \ Set A = r4

 JSR PIX                \ Draw a pixel at screen coordinate (X, -A), i.e. at
                        \ (r3, -r4), where (r3^2 + r4^2) / 256 >= 17
                        \
                        \ Negating a random number from 0 to 255 still gives a
                        \ random number from 0 to 255, so this is the same as
                        \ plotting at (x, y) where:
                        \
                        \   x = random number from 0 to 255
                        \   y = random number from 0 to 255
                        \   (x^2 + y^2) div 256 >= 17
                        \
                        \ which is what we want

.PLC2

 DEC CNT2               \ Decrement the counter in CNT2 (the low byte)

 BNE PLL2               \ Loop back to PLL2 until CNT2 = 0

 DEC CNT2+1             \ Decrement the counter in CNT2+1 (the high byte)

 BNE PLL2               \ Loop back to PLL2 until CNT2+1 = 0

Code variation 1 of 1Other (e.g. bug fix, optimisation)

The cassette and Electron versions contain various bits of copy protection code injected into part 2 of the Saturn-drawing routine in the loader.

This variation is blank in the Disc (flight), 6502 Second Processor and Master versions.

Tap on a block to expand it, and tap it again to revert.

Cassette
Electron
 LDX MHCA               \ Set the low byte of BLPTR(1 0) to the contents of MHCA
 STX BLPTR              \ (which is &CA), so we now have BLPTR(1 0) = &03CA,
                        \ which we will use in the IRQ1 handler (this has
                        \ nothing to do with drawing Saturn, it's all part of
                        \ the copy protection)

 LDX #&C6               \ Set the low byte of BLN(1 0) to &C6, so we now have
 STX BLN                \ BLN(1 0) = &03C6, which we will use in the IRQ1
                        \ handler (this has nothing to do with drawing Saturn,
                        \ it's all part of the copy protection)
 LDX #&CA               \ This is normally part of the copy protection, but it's
 NOP                    \ been disabled in this unprotected version so this has
 STX BLPTR              \ no effect (though the crackers presumably thought they
 LDX #&C6               \ might as well still set the values just in case)
 STX BLN